asp con xml

[monxas]

estoy haciendo una base de datos de libros, y me gustaria que solo metiendo el isbn y mediante un web service recoger la info de los libros sin meterlos a mano.
encontre este:
http://isbndb.com

que devuelve un xml, aunque no tiene muchosl ibros en español, pero es mejor que nada...

el tema es que no se como recoger los datos con asp.
de momento tengo esto:

Código asp:

m_n_isbn = Request.Form("isbn")
url="http://isbndb.com/api/books.xml?access_key=AWMA4LDX&index1=isbn&value1=" & m_n_isbn
 
 
 
 Set objXML = Server.CreateObject("Microsoft.XMLDOM")
 Set objLst = Server.CreateObject("Microsoft.XMLDOM")
 objXML.async = False
 objXML.Load (url)
 If objXML.parseError.errorCode <> 0 Then
     response.write(objXML.parseError.errorCode & "<br>")
     response.write(objXML.parseError.reason & "<br>")
     response.write(objXML.parseError.line & "<br>")
     response.write(objXML.parseError.srcText & "<br>")
 End If
 
 Set objLst = objXML.getElementsByTagName("*")
 
 For i = 0 to (objLst.length - 1)
 
    If objLst.item(i).nodeName = "title" Then
      title = objLst.item(i).text
      response.write(title)
    End If
    Exit For
 Next
 

un xml generado seria:
http://isbndb.com/api/books.xml?acce...ue1=0596002068

la verdad es que toy un poco perdido y no consigo entenderlo bien, a ver si alguien me echa una mano!

[monxas]

nadie sabe del tema??

[mc_quake]

Código asp:

<&#37;  
    'archivo para ejemplos: [datos.xml]
    
    '<sitio>
    '   <columnas>
    '       <izq>10</izq>
    '       <der>20</der>
    '       <cen>30</cen>
    '    </columnas>
    '    <columnas2>
    '       <izq>40</izq>
    '       <der>50</der>
    '       <cen>60</cen>
    '   </columnas2>
    '   <nombre>Mi Sitio</nombre>
    '</sitio>
    
    function leerXML(archivoXML, nombreDato)
 
        ' Los parametros son:
        '   -archivoXML: ruta del archivo XML
        '   -nombreDato: nombre del dato a buscar
        '
        ' ej:
        '
        ' a = leerXML(server.mappath("datos.xml"), "columnas/der") 'a = "20"
        ' b = leerXML(server.mappath(".") & "\datos.xml", "nombre") 'b = "Mi Sitio"
    
        'Creo el objeto de XMLDOM
        set xml = server.CreateObject("Microsoft.XMLDOM")
        
        'No dejo que el archivo se edite si está en uso
        xml.async="false"
        
        'Cargo el archivo
        xml.load(archivoXML)
        
        'si el archivo XML tiene errores
        if xml.parseError.errorCode <> 0 then
            response.Write("<font face = ""arial"" size = ""-1""> Hay un error en el archivo XML (<b>" & archivoXML & "</b>): <b>" & xml.parseError.reason & "<p>")  
            response.Write("</b>Linea: <b>" & xml.parseError.line & " </b>Posicion: <b>" & xml.parseError.linepos)  
            response.end  
        end if  
        
        'Obtengo los elementos del archivo
        set elementos = xml.documentElement
        
        'Obtengo el nodo deseado(dato deseado)
        set nodo = elementos.selectSingleNode(nombreDato)
        
        'si no se pudo cargar el nodo
        if nodo is nothing then
            response.Write("<font face = ""arial"" size = ""-1""> Hay un error en el archivo XML (<b>" & archivoXML & "</b>) con el nodo buscado (<b>" & nombreDato & "</b>) : <b>El nodo buscado no existe")  
            response.end  
        end if
        
        'obtengo el texto del nodo y lo devuelvo
        leerXML = nodo.text
        
        set nodo = nothing
        set elementos = nothing
        set xml = nothing
    end function
    
    
    sub modificarXML(archivoXML, nombreDato, nuevoValor)
 
        ' Los parametros son:
        '   -archivoXML: ruta del archivo XML
        '   -nombreDato: nombre del dato a modificar
        '   -nuevoValor: nuevo valor para el dato encontrado
        '
        ' ej:
        '
        ' a = modificarXML(server.mappath("datos.xml"), "columnas/der", "10") '<der>10</der>
        ' b = modificarXML(server.mappath(".") & "\datos.xml", "nombre", "Nuestro Sitio") '<nombre>Nuestro Sitio</nombre>
    
        'Creo el objeto de XMLDOM
        set xml = server.CreateObject("Microsoft.XMLDOM")
        
        'No dejo que el archivo se edite si está en uso
        xml.async="false"
        
        'Cargo el archivo
        xml.load(archivoXML)
 
        'si el archivo XML tiene errores
        if xml.parseError.errorCode <> 0 then
            response.Write("<font face = ""arial"" size = ""-1""> Hay un error en el archivo XML (<b>" & archivoXML & "</b>): <b>" & xml.parseError.reason & "<p>")  
            response.Write("</b>Linea: <b>" & xml.parseError.line & " </b>Posicion: <b>" & xml.parseError.linepos)  
            response.end  
        end if  
        
        'Obtengo los elementos del archivo
        set elementos = xml.documentElement
        
        'Obtengo el nodo deseado(dato deseado)
        set nodo = elementos.selectSingleNode(nombreDato)
        
        'si no se pudo cargar el nodo
        if nodo is nothing then
            response.Write("<font face = ""arial"" size = ""-1""> Hay un error en el archivo XML (<b>" & archivoXML & "</b>) con el nodo buscado (<b>" & nombreDato & "</b>) : <b>El nodo buscado no existe")  
            response.end  
        end if
        'obtengo el texto del nodo y lo devuelvo
        nodo.text = nuevoValor
        
        xml.save archivoXML
        
        set nodo = nothing
        set elementos = nothing
        set xml = nothing
    end sub
%>
 

[monxas]

muchas gracias por contestar, le echo un vistazo!