Foros del Web » Programando para Internet » ASP Clásico »

crear un global.asa

Estas en el tema de crear un global.asa en el foro de ASP Clásico en Foros del Web. Mi consulta es la siguiente: Yo no tengo en mi maquina creado ningun global.asa, alguien sabe como crearlo ??? uso el IIS 5.0 Yo voy ...
  #1 (permalink)  
Antiguo 14/02/2004, 02:22
 
Fecha de Ingreso: febrero-2004
Mensajes: 1
Antigüedad: 21 años, 1 mes
Puntos: 0
crear un global.asa

Mi consulta es la siguiente:
Yo no tengo en mi maquina creado ningun global.asa, alguien sabe como crearlo ??? uso el IIS 5.0
Yo voy a dreamweaver y al poner los distintos parametros me dice que esta mal la codificacion, y me bloquea las distintas ventas del editor web.-

gracias

Última edición por rofimarwm; 14/02/2004 a las 02:23
  #2 (permalink)  
Antiguo 14/02/2004, 12:24
Avatar de luisvasquez  
Fecha de Ingreso: diciembre-2003
Ubicación: Venezuela
Mensajes: 879
Antigüedad: 21 años, 3 meses
Puntos: 6
Hola..el archivo global.asa se usa basicamente para obtener variables cuando se inician y finalizan sesiones, aunque teoricamente puedes hacer lo que quieras alli, tomando en cuenta que se ejecuta solo cuando arranca una sesión de usuario...allí va un ejemplo de mi global.asa que cuenta los usuarios activos y la cantidad de visitantes :

<SCRIPT LANGUAGE="VBScript" RUNAT="Server">

Sub Application_OnStart
' Coloca el contador en cero cuando se reincia el server
Application("ActiveUsers") = 0
Application("Visits") = 0

End Sub

Sub Session_OnStart
' Timeout de las sesiones de usuario
Session.Timeout = 20
' cuando comenzó la sesión de este usuario
Session("Start") = Now
' Incrementa los visitantes activos
Application.Lock
Application("ActiveUsers") = Application("ActiveUsers") + 1
Application.UnLock

Application.Lock
' Incrementa el contador de visitas
Application("Visits") = Application("Visits") + 1
Application.UnLock

End Sub

Sub Session_OnEnd
' Decrementa los visitantes activos
al finalizar la sesion
Application.Lock
Application("ActiveUsers") = Application("ActiveUsers") - 1
Application.UnLock
End Sub

</SCRIPT>

solo copia este codigo y grabalo con el nombre global.asa, colocandolo en el root de tu site...

Ahora bien, si quieres darle utilidad a las variables creadas en este caso, inserta unas lineas de codigo en cualquier parte de tu site para ver los valores, asi:

<%@ Language=VBScript %>
<HTML>
<HEAD>
<TITLE>Usuarios activos y total de Visitas</TITLE>
</HEAD>
<BODY>

<B><FONT COLOR="#CC0000">
<%
Response.write Application("ActiveUsers") & " active users<BR>"
Response.Write Application("Visits") & " total visits"
%></FONT> </B>

</BODY>
</HTML>

claro...solo los response.write son necesarios si vas a insertarlos en una página que ya existe...espero haberte ayudado,

Luis
Atención: Estás leyendo un tema que no tiene actividad desde hace más de 6 MESES, te recomendamos abrir un Nuevo tema en lugar de responder al actual.
Respuesta




La zona horaria es GMT -6. Ahora son las 06:44.