Arrays Asociativos con varias dimensiones

[zacktagnan]

Hola a tod@s:

Estoy queriendo hacer lo equivalente a este código de PHP en ASP relativo a arrays asociativos:

Código PHP:

   
$datos_pais =        array(
                    'es' => array(
                                'nombre' => 'España',
                                'moneda' => 'peseta'
                            ),
                    'fr' => array(
                                'nombre' => 'Francia',
                                'moneda' => 'franco'
                            )
                    );
 
$codPais = 'es';
echo 'El país llamado '.$datos_pais[$codPais]['nombre'].' tenía una moneda llamada ['.$datos_pais[$codPais]['moneda'].'] antes del Euro';
//Esto debería mostrar el siguiente texto
//El país llamado España tenía una moneda llamada [peseta] antes del Euro 
   

¿Cómo sería este ejemplo de ARRAY para ASP clásico en VBScript?

Lo único que he llegado a encontrar en los buscadores es que los arrays asociativos en ASP se hacen a través del objeto Dictionary.
Pero solamente he llegado a encontrar ejemplos para una sola dimensión.

[zacktagnan]

¿Qué, nadie tiene idea de cómo hacer lo que pido?

Yo, con lo del Dictionary, solamente llego a construir un array de una sola dimensión tal y como sigue:

Código ASP:

Dim datos_pais, codPais
Set datos_pais = CreateObject("Scripting.Dictionary")
datos_pais.Add "gr", "Grecia"
datos_pais.Add "sr", "Serbia"
datos_pais.Add "eg", "Egipto"
 
codPais = "eg"
Response.Write("El país pedido con el código [" & codPais & "] tiene el nombre de " & UCase(datos_pais(codPais)) & ".")
 
''''Esto debería mostrar el siguiente texto:
''''El país pedido con el código [eg] tiene el nombre de EGIPTO.
 

Incluso, he encontrado un ejemplo en el que en la columna del valor se mete un Array:

Código ASP:

Dim myDictionary
Set myDictionary = CreateObject("Scripting.Dictionary")
 
myDictionary.Add "a", Array("a1","a2")
myDictionary.Add "b", Array("b1","b2")
myDictionary.Add "c", Array("c1","c2")
 

A ver si alguien aporta más ideas más acordes a lo pedido.

[zacktagnan]

Bueno, pues parece que ya he encontrado uns forma de hacer lo que pretendía, buscando algo más por Internet.
Porque por aquí, últimamente, no es muy frecuente que alguien me exponga una solución a los temas que abro.

Sea como sea, ahí va el ejemplo de cómo hacer el mismo array equivalente al expuesto en PHP y varias formas de recorrer el array para sacar los valores correspondientes:

Código ASP:

Dim datos_pais
Set datos_pais = CreateObject("Scripting.Dictionary")
''''Creando una segunda dimensión para cada elemento de la primera dimensión
datos_pais.Add "es", CreateObject("Scripting.Dictionary")
datos_pais.Add "fr", CreateObject("Scripting.Dictionary")
''''Asignando valores a cada índice
datos_pais("es")("nombre")  = "España"
datos_pais("es")("moneda")  = "la peseta"
''''Otra forma de asignar valores
datos_pais("fr").Add "nombre",  "Francia"
datos_pais("fr").Add "moneda",  "el franco"
 
    Response.Write("<br />")
For Each key_datos_pais In datos_pais
    ''''Dos formas de leer los valores
    '''' 1ª Forma >> elArray(indice_1)(indice_2)
    '''' 2ª Forma >> elArray.Item(indice_1).Item(indice_2)
    Response.Write("<br />&bull; En el país de " & datos_pais(key_datos_pais)("nombre") & ", con el código [" & UCase(key_datos_pais) & "], el nombre de la moneda antes usada era " & datos_pais.Item(key_datos_pais).Item("moneda") & ".")
Next
''''===============================================
''''Esto debería mostrar el siguiente texto:
''''• En el país de España, con el código [ES], el nombre de la moneda antes usada era la peseta.
''''• En el país de Francia, con el código [FR], el nombre de la moneda antes usada era el franco.
 
    Response.Write("<br />")
For Each key_datos_pais In datos_pais
    Response.Write("<br />&bull; [" & UCase(key_datos_pais) & "]")
    For Each key_dato In datos_pais(key_datos_pais)
    Response.Write("<br />&nbsp;&nbsp;&nbsp;&nbsp;>> " & UCase(key_dato) & ": " & datos_pais(key_datos_pais)(key_dato))
    Next
Next
''''===============================================
''''Esto debería mostrar el siguiente texto:
''''• [ES]
''''    >> NOMBRE: España
''''    >> MONEDA: la peseta
''''• [FR]
''''    >> NOMBRE: Francia
''''    >> MONEDA: el franco
 

Pues eso, para todo el que pueda aprovecharse ... ¡Aprovecha!