Procesar etiqueta dentro de texto - XML -> XSL [Solucionado]

[jam1138]

Buenas. Tengo una cuestión simple pero me doy cuenta que antes no la había intentado. Se trata de que tengo texto dentro de una etiqueta, y dentro de ese texto puede haber otras etiquetas (como los <strong>, <em>, <span> de HTML). Necesito cachar ese texto y tratarlo para igual encerrarlo dentro de otras etiquetas, esta vez tipo BBCode.

He aquí un XML de ejemplo:

Código xml:

<?xml version="1.0" ?>
<seccion>
    <title>Titulo</title>
    <para>
        Lorem <def>ipsum</def> postea complectitur eos in, mandamus disputationi 
        mediocritatem vix ei.
    </para>
</seccion>
 

Aquí el XSL que estoy --hasta ahora-- aplicando:

Código xml:

<?xml version="1.0" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="seccion">
        [TITLE]<xsl:value-of select="title"/>[/TITLE]
        <xsl:value-of select="normalize-space(para)" />
    </xsl:template>
</xsl:styleshee
 

MI salida actual:

[TITLE]Titulo[/TITLE]
Lorem ipsum postea complectitur eos in, mandamus disputationi mediocritatem vix ei.

Lo que quiero conseguir (negritas de mi parte):

[TITLE]Titulo[/TITLE]
Lorem [DEF]ipsum[/DEF] postea complectitur eos in, mandamus disputationi mediocritatem vix ei.

Entonces, que sé cómo accesar a el contenido de la etiqueta <def> (para/def) pero lo que no se me ocurre ahora es cómo ... tratarlo para que el contenido (el texto) quede de la misma forma, colocarlo en el mismo lugar.

Si alguien me hecha una pista, os agradeceré .

[monoswim]

Una pregunta, porque guardas en el XML <def> si luego debes mostrarlo como [def]...Podrías guardarlo directamente como [def] y mostrar literalmente lo que tiene la etiqueta...

Lo que dices de encontrar los para/def y dejarlos en el mismo lugar NO SE PUEDE hace meses que tuve ese problema y me rompí la cabeza buscando la solución...no la encontré

Te sirve lo que te puse al principio ?

un abrazo grande...

[jam1138]

Iniciado por monoswim

Una pregunta, porque guardas en el XML <def> si luego debes mostrarlo como [def]...Podrías guardarlo directamente como [def] y mostrar literalmente lo que tiene la etiqueta...

¿Te refieres a tener [DEF] en el XML fuente?; no puedo, no tengo control sobre ese contenido :-/.

Se me hace difícil de creer no se pueda. La verdad es que no he visto nada así en los ejemplos de XSL. Intentaré buscarle, sino creo poderlo solucionar echando mano de PHP... a ver qué logro.

[jam1138]

Uf, uf, uf y recontra uf! :

Primero, aunque sabía no iba por ahí, me puse a buscar sobre el reemplazo de cadenas (no va por ahí porque es otro nodo XML, no es solo una cadena) con la esperanza de encontrar algo. Me topé con la función translate(), pero ésta solo reemplaza caracteres, pero teniendo más noción recurrí a Google y encontré una función para remplazar cadenas con xsl que solo copié y pegué (haciendo caso de las instrucciones ):

Código xml:

<xsl:template name="replace-string">
  <xsl:param name="text"/>
  <xsl:param name="from"/>
  <xsl:param name="to"/>
 
  <xsl:choose>
    <xsl:when test="contains($text, $from)">
 
      <xsl:variable name="before" select="substring-before($text, $from)"/>
      <xsl:variable name="after" select="substring-after($text, $from)"/>
      <xsl:variable name="prefix" select="concat($before, $to)"/>
 
      <xsl:value-of select="$before"/>
      <xsl:value-of select="$to"/>
      <xsl:call-template name="replace-string">
        <xsl:with-param name="text" select="$after"/>
        <xsl:with-param name="from" select="$from"/>
        <xsl:with-param name="to" select="$to"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$text"/>
    </xsl:otherwise>
  </xsl:choose>
 
</xsl:template>
 

Para utilizarla, hay que invocar el template de la siguiente manera:

Código xml:

<xsl:call-template name="replace-string">
  <xsl:with-param name="text" select="path/del/nodo"/>
  <xsl:with-param name="from" select="'textoAbuscar'"/>
  <xsl:with-param name="to" select="'textoParaReemplazar'"/>
</xsl:call-template>
 

Entonces, yo solo tomo el contenido del nodo, y lo reemplazo por sí mismo concatenado con el BBCode correspondiente (se me ocurrió, cualquier otra idea es bienvenida). Entonces, el XSL me quedó de la siguiente manera:

Código xml:

<?xml version="1.0" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
 
<xsl:template match="seccion">
    [TITLE]<xsl:value-of select="title"/>[/TITLE]
    <xsl:variable name="def" select="para/def" />
    <xsl:call-template name="replace-string">
        <xsl:with-param name="text" select="normalize-space(para)"/>
        <xsl:with-param name="from" select="$def"/>
        <xsl:with-param name="to" select="concat('[DEF]',$def,'[/DEF]')"/>
    </xsl:call-template>
</xsl:template>
 
<!--
    Template para reemplazar cadenas.
    [url]http://www.nectil.com/Public/ManualText.php?ID=2586&manualID=2547[/url]
    -->
<xsl:template name="replace-string">
    <xsl:param name="text"/>
    <xsl:param name="from"/>
    <xsl:param name="to"/>
 
    <xsl:choose>
      <xsl:when test="contains($text, $from)">
          <xsl:variable name="before" select="substring-before($text, $from)"/>
          <xsl:variable name="after" select="substring-after($text, $from)"/>
          <xsl:variable name="prefix" select="concat($before, $to)"/>
 
          <xsl:value-of select="$before"/>
          <xsl:value-of select="$to"/>
          <xsl:call-template name="replace-string">
            <xsl:with-param name="text" select="$after"/>
            <xsl:with-param name="from" select="$from"/>
              <xsl:with-param name="to" select="$to"/>
          </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="$text"/>
        </xsl:otherwise>
    </xsl:choose>
 
</xsl:template>
</xsl:stylesheet>
 

Y así es que consigo el objetivo buscado... quedo tranquilo por ahora. Ojalá a alguien más le sirva, cualquier comentario bienvenido.

[jam1138]

Primero: se me pasó comentar que para XSL versión 2 hay una función replace() con la que no se tendría que recurrir a este template, por desgracia no pude hacer uso de esto.

Segundo: Justo ahora que lo envié , descubro hay un pequeño problema. Suponiendo tengo el siguiente XML:

Código xml:

<?xml version="1.0" ?>
<seccion>
    <title>Titulo</title>
    <para>
        Lorem <def>ipsum</def> postea ipsum complectitur eos in, mandamus disputationi 
        mediocritatem vix ei.
    </para>
</seccion>
 

cuando aplique mi plantilla obtendría el siguiente resultado (negritas donde ocurre el reemplazo):

[TITLE]Titulo[/TITLE]
Lorem [DEF]ipsum[/DEF] postea [DEF]ipsum[/DEF] complectitur eos in, mandamus disputationi mediocritatem vix ei.

lo cual no sería lo correcto. Se trata solo de reemplazar el nodo; lo correcto debería de ser:

[TITLE]Titulo[/TITLE]
Lorem [DEF]ipsum[/DEF] postea ipsum complectitur eos in, mandamus disputationi mediocritatem vix ei.

... para mi suerte, las probabilidades de que un error así ocurra son pocas (son palabras muy específicas), pero no deja de ser un error. Por ahora descanso, ya veré.

Abúr!

[Ek-Balam]

Saludos, Jam.

Yo te iba a proponer que usaras un DTD en el cual crearas un par de ENTITY para obtener directamente las tags [def] y [/def], pero leo que tú no tienes acceso al
archivo xml.

El ejemplo que hice es el siguiente (nombré los archivos como "p1.xml" y "p1.xsl", para hacer pruebas). El XML:


<?xml version="1.0" encoding="iso-8859-1"?>
<?xml-stylesheet type="text/xsl" href="p1.xsl"?>
<!DOCTYPE seccion[
<!ELEMENT seccion (title, para)>
<!ELEMENT title (#PCDATA)>
<!ELEMENT para (#PCDATA)>
<!ENTITY XdefX "[def]">
<!ENTITY XxdefX "[/def]">
]>
<seccion>
<title>Titulo</title>
<para>Lorem &XdefX; ipsum &XxdefX; postea complectitur eos in,
mandamus disputationi mediocritatem vix ei.</para>
</seccion>


El XSL:



<?xml version="1.0" encoding="iso-8859-1" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:template match="seccion">
[TITLE]<xsl:value-of select="title"/>[/TITLE]
<xsl:value-of select="para" />
</xsl:template>
</xsl:stylesheet>


El resultado:

[TITLE]Titulo[/TITLE] Lorem [def] ipsum [/def] postea complectitur eos in, mandamus disputationi mediocritatem vix ei.


Como verás, con el DTD se hubieran creado directamente las tags para bbcode, pero si no puedes acceder al xml mi ayuda está de más.
Espero halles solución.
Buen día.
=0)

[jam1138]

Gracias por la sugerencia Ek-Balam, entiendo lo que dices, pero no tengo acceso al XML... al menos no de primera mano. Son recursos que se extraen externamente, de vez en cuando han de hacer cambios externos, fuera de mi control, tengo que agarrarlos y transformarlos para trabajar con el resultado.

Pero bueno, ahora intenté esto:

Código xml:

<?xml version="1.0" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="text" />
 
   <xsl:template match="/">
       <xsl:for-each select="./*">
           <xsl:apply-templates />
       </xsl:for-each>
   </xsl:template>
 
   <xsl:template match="title">
       <xsl:text>[TITLE]</xsl:text>
       <xsl:value-of select="." />
       <xsl:text>[/TITLE]</xsl:text>
   </xsl:template>
 
   <xsl:template match="def">
       <xsl:text>[DEF]</xsl:text>
       <xsl:value-of select="." />
       <xsl:text>[/DEF]</xsl:text>
   </xsl:template>
 
</xsl:stylesheet>
 

Trato directamente el nodo <def> sin tratar el <para> y funciona, pero ahora tengo problema con los espacios, pues la tabulación y el fin de línea se conservan y es algo que no debería. Este es (mas o menos) mi salida:

Código:

       [TITLE]Titulo[/TITLE]

               Lorem [DEF]ipsum[/DEF] postea ipsum complectitur eos in, mandamus disputationi
               mediocritatem vix ei.

El XML viene con saltos de línea si el texto pasa de 80 caracteres, pero yo necesito el texto corrido. Además, por la indentación de los nodos del XML igual se indenta el resultado (y hay saltos de línea extras), lo cuál necesito quitar. No puedo aplicar normalize-space() a para porque entonces, regreso al problema inicial (tratar <def> y colocarlo donde tiene que ir). Igual y se puede solucionar esto de otra manera; ¿ideas?.

[Ek-Balam]

Saludos de nuevo, Jam.

Estaba viendo en tu archivo .xsl un detallito. Quizá sea lo que te pueda
servir:

Elimina el "<xsl:output method="text" />" y el "<xsl:for-each select="./*">........</xsl:for-each>".
Y dentro del .xsl agrega una tabla.

El ejemplo sería así:


<?xml version="1.0" encoding="iso-8859-1" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">

<table><tr><td>
<xsl:apply-templates />
</td></tr></table>

</xsl:template>

<xsl:template match="title">

<xsl:text>[TITLE]</xsl:text>
<xsl:value-of select="." />
<xsl:text>[/TITLE]</xsl:text>

</xsl:template>

<xsl:template match="def">
<xsl:text>[DEF]</xsl:text>
<xsl:value-of select="." />
<xsl:text>[/DEF]</xsl:text>

</xsl:template>

</xsl:stylesheet>


Probé tu código inicial con el IE7, FF y Ópera, y únicamente en el IE7 colocaba
el texto de corrido; mientras que en los otros 2, dejaba el salto de línea.
Ahora, yo he probado la modificación al xsl y en los 3 navegadores deja el texto
en una única línea.
Espero que esto sea lo que necesitas.
Buen día.
=0)

[HackmanC]

Hola,

Posiblemente funcione así:

Código xml:

<xsl:template match="/">
<pre>
<xsl:for-each select="seccion">[TITLE]<xsl:value-of select="normalize-space(title)"/> : [/TITLE]<xsl:for-each select="para">
    <xsl:apply-templates select="."/>
  </xsl:for-each>
</xsl:for-each>
</pre>
</xsl:template>
 
<xsl:template match="para/def">[DEF]<xsl:value-of select="normalize-space(.)"/>[/DEF]</xsl:template>
<xsl:template match="para/text()">[BLANK]<xsl:value-of select="normalize-space(.)"/>[/BLANK]</xsl:template>
 

Saludos,

[jam1138]

Ek-Balam: Perdón por no mencionarlo, creí estaba implícito: La salida tendría que ser texto plano, no HTML. De lo que menciones, veo son cambios para tratarlo como HTML y verlo a través de un navegador, perdona las molestias.

HackmanC: ¡Gracias!. ¡Tan simple! . La manera de acceder a el texto del nodo es lo que necesitaba; ese 'match="para/text()"' ahí y aplico el normalize-space(.) al contenido. Gracias, diste en el clavo .

Entonces, paso el XSL final (ahora sí) con los siguientes cambios:
- Agrego <xsl:strip-space elements="*"/>. Esto elimina los espacios sobrantes de todos los elementos, osea, la tabulación y saltos de línea entre nodos. Estoy trabajando con texto plano , es necesario esto.
- Agrego el template para eliminar los saltos de línea (limitado a 80 caracteres) del nodo <para>, gracias al código de HackmanC.
- Agrego un salto de línea después de [/TITLE]. Nuevamente, al estar trabajando con texto plano, los saltos de línea son igual caracteres implicitos.

Código xml:

<?xml version="1.0" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 
<xsl:output method="text" />
<xsl:strip-space elements="*" />
 
<xsl:template match="/">
   <xsl:for-each select="./*">
      <xsl:apply-templates />
   </xsl:for-each>
</xsl:template>
 
<xsl:template match="title">
   <xsl:text>[TITLE]</xsl:text>
   <xsl:value-of select="." />
   <xsl:text>[/TITLE]
</xsl:text>
</xsl:template>
 
<xsl:template match="def">
   <xsl:text>[DEF]</xsl:text>
   <xsl:value-of select="." />
   <xsl:text>[/DEF]</xsl:text>
</xsl:template>
 
<xsl:template match="para/text()">
   <xsl:value-of select="normalize-space(.)"/>
</xsl:template>
 
</xsl:stylesheet>
 

Y voalá! . Muchas gracias a todos, creo ahora sí está solucionado, ojalá le sirva a alguien más.