nombres de archivos en bases de datos

[keikos]

Hola amigos.
espero me puedan orientar.

alguien tiene alguna idea. de lo siguiente:

estoy en una empresa, donde todo lo manejan en WORD. por ejemplo sus cotizaciones , y para hacer una busqueda. tienen que hacerlo por texto, y es mucho recurso del sistema, etc.

bueno la idea es q se va a implementar, un sistema, pero ahorita lo que quiero hacer es que todos los archivos de word que existen, una rutina los indexe en una base de datos. esos archivos, para q la busqueda sea mas rapida.
espero haberme explicada un saludo Y GRACIAS

[Taribo007]

No se que programas quieres usar. Te propongo que uses access. Crea una tabla llamada Archivos. En ella un campo llamado NombreArchivo.

Luego, esta funcion recorre la carpeta que le pases como argumento, ademas de las subcarpetas, y va introduciendo en la tabla todos los documentos de word que encuentre. Pega esta funcion en un modulo:

Public Function BuscaArchivos(nomCarpeta As String)
Dim ObjetoFSO As Object
Dim Carpeta As Object
Dim SubCarpeta As Object
Dim Archivos As Object
Dim Archivo As Object
Dim rst As DAO.Recordset

Set ObjetoFSO = CreateObject("Scripting.FileSystemObject")
Set Carpeta = ObjetoFSO.GetFolder(nomCarpeta)
Set Archivos = Carpeta.Files
Set rst = CurrentDb.OpenRecordset("Archivos")

For Each Archivo In Archivos
'Buscamos en los archivos de la carpeta
If Right(Archivo.Name, 4) = ".doc" Then
rst.AddNew
rst!NombreArchivo = Archivo.Name
rst.Update
End If
Next
Set Archivos = Nothing
rst.Close
Set rst = Nothing

' Buscamos en las carpetas y subcarpeta haciendo
'llamadas recursivas a la funcion
For Each SubCarpeta In Carpeta.SubFolders
BuscaArchivos (nomCarpeta & "\" & SubCarpeta.Name)
Next
Set Carpeta = Nothing
Set ObjetoFSO = Nothing

End Function


Y la llamas asi desde, por ejemplo, un boton:

BuscaArchivos ("C:\Demo\Carpeta1")

Un saludo