Cargar programa automaticamente

[Alice]

Hola:
Tengo la siguiente pregunta:

Puedo cargar un programa en forma automatica al momento de cumplirse una condición ¿?

me explico:

el usuario selecciona una opción que señala adjuntar archivos por correo; al momento de él elegir esa opción el programa de correo que tiene por defecto en su pc se abra automaticamente sin necesidad de colocar un link en el programa el que haya que presionar para abrir el programa de correo..

SI¿? como¿?


Desde ya agradezco su ayuda chicos... dirección en donde pueda encontrar algo relacionado, ayuda, todo se recibe , gracias

Salu2,

[e-miliox]

pero donde o a traves de que quieres cargar dicho programa?!

en el windows? en un programa en especifico? donde?

saludos

[lucasiramos]

Hola. Si estas trabajando en VB6, con la función Shell() podes ejecutar cualquier programa que tengas. Solo debes especificar la ruta.
Espero que te sirva. Saludos.
Lucas

[Beakdan]

Alice:
También puedes usar la función ShellExecute de la API de Windows. La puedes usar como si le pasaras un comando a la opción ejecutar del menu de Inicio de Windows. Puedes utilizar dicha función también para abrir la aplicación asignada por defecto a un tipo de archivo. En este caso, le pasamos una cadena de texto con el formato que usarías en un link "mailto:" (puedes usarla para abrir también un link http://).
En Win98 podía asignar también un archivo adjunto, pero ahora por lo menos Outlook Express en XP ignora esa parte (supongo que es alguna característica de seguridad).
Pega esto en un nuevo form:

Código:

Option Explicit

Const SW_SHOWNORMAL = 1
Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" ( _
        ByVal hwnd As Long, _
        ByVal lpOperation As String, _
        ByVal lpFile As String, _
        ByVal lpParameters As String, _
        ByVal lpDirectory As String, _
        ByVal nShowCmd As Long) As Long
        
Private Sub Form_Load()
    SendMail "[email protected]", "Saludos!", _
            "En un lugar de la Mancha de cuyo nombre no quisiera acordarme..."
            
End Sub

Private Sub SendMail( _
        ByVal sDest As String, _
        ByVal sSubject As String, _
        ByVal sBody As String)
        
Dim sMsg As String

'***************************
'Esto solía funcionar
'**********************
    'sMsg = "mailto:" & sDest & _
            "?subject=" & sSubject & _
            "&attach=" & """c:\archivo.ext""" & _
            "&body=" & sBody

    sMsg = "mailto:" & sDest & _
            "?subject=" & sSubject & _
            "&body=" & sBody
            
    ShellExecute Me.hwnd, vbNullString, sMsg, vbNullString, vbNullString, SW_SHOWNORMAL
End Sub

Ojalá te sirva.

Saludos.