alguien sabe como se utiliza el "ExitWindowsEx" en vb

[vampirito]

alguien me podria ayudar ya que estoy atorado con esta parte, intento reiniciar el sistema despues de instalar un programita, encontre esta forma, pero no se muy bien como utilizarla, este es mi codigo:


Private Sub Command3_Click()
Dim val, driver, val1
'Dim i As Integer
driver = App.Path
val = Shell(driver + "\winzip\setup.exe /s", 1)
val1 = MsgBox("Reiniciar Sistema", vbOKOnly, "Reiniciar")
ExitWindowsEx 2, 0 'Reinicia el Sistema
'i = ExitWindowsEx(1, 0&) 'Este apaga el sistema
End Sub

[GeoAvila]

mira crea un formulario con un ComboBox que se llama "cmbTipoApagado" un boton con el nombre de "btnApagar" un CheckBox con el nombre "optForzar", pegas esto en el codigo del form...

Código:

Option Explicit
' CONSTANTES Y DECLARACIONES PARA SALIR DE WINDOWS
' Cerrar todos los programas e iniciar la sesión como
' un usuario distinto
Private Const EWX_LOGOFF = 0
' Apagar el equipo
Private Const EWX_SHUTDOWN As Long = 1
' Reiniciar el equipo
Private Const EWX_REBOOT = 2
' Forzar el apagado. Los ficheros abiertos se pueden perder. Las
' aplicaciones no preguntarán si se quieren guardar las modificaciones
Private Const EWX_FORCE As Long = 4
'
Private Declare Function ExitWindowsEx Lib "user32" (ByVal _
        dwOptions As Long, ByVal dwReserved As Long) As Long

'DECLARACIONES PARA OBTENER EL PERMISO NECESARIO EN NT
Private Type LUID
    UsedPart As Long
    IgnoredForNowHigh32BitPart As Long
End Type
Private Type TOKEN_PRIVILEGES
    PrivilegeCount As Long
    TheLuid As LUID
    Attributes As Long
End Type
Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
Private Declare Function OpenProcessToken Lib "advapi32" (ByVal _
        ProcessHandle As Long, ByVal DesiredAccess As Long, TokenHandle As Long) As Long
Private Declare Function LookupPrivilegeValue Lib "advapi32" _
        Alias "LookupPrivilegeValueA" _
        (ByVal lpSystemName As String, ByVal lpName As String, lpLuid _
        As LUID) As Long
Private Declare Function AdjustTokenPrivileges Lib "advapi32" _
        (ByVal TokenHandle As Long, ByVal DisableAllPrivileges As Long, _
        NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Long, _
        PreviousState As TOKEN_PRIVILEGES, ReturnLength As Long) As Long
Private Sub AdjustToken()
Const TOKEN_ADJUST_PRIVILEGES = &H20
Const TOKEN_QUERY = &H8
Const SE_PRIVILEGE_ENABLED = &H2
Dim hdlProcessHandle As Long
Dim hdlTokenHandle As Long
Dim tmpLuid As LUID
Dim tkp As TOKEN_PRIVILEGES
Dim tkpNewButIgnored As TOKEN_PRIVILEGES
Dim lBufferNeeded As Long

hdlProcessHandle = GetCurrentProcess()
OpenProcessToken hdlProcessHandle, (TOKEN_ADJUST_PRIVILEGES Or TOKEN_QUERY), hdlTokenHandle
' Get the LUID for shutdown privilege
LookupPrivilegeValue "", "SeShutdownPrivilege", tmpLuid
tkp.PrivilegeCount = 1 ' One privilege to set
tkp.TheLuid = tmpLuid
tkp.Attributes = SE_PRIVILEGE_ENABLED ' Enable the shutdown privilege in the access token of this process
AdjustTokenPrivileges hdlTokenHandle, False, tkp, Len(tkpNewButIgnored), tkpNewButIgnored, lBufferNeeded
End Sub

Private Sub btnApagar_Click()
Dim ret As Long, Forzar As Long

AdjustToken
Forzar = IIf(optForzar.Value, 4, 0)
ret = ExitWindowsEx(cmbTipoApagado.ItemData(cmbTipoApagado.ListIndex) + Forzar, 0&)
End Sub


Private Sub Form_Load()
cmbTipoApagado.AddItem "LOGOFF"
cmbTipoApagado.ItemData(cmbTipoApagado.NewIndex) = EWX_LOGOFF
cmbTipoApagado.AddItem "SHUTDOWN"
cmbTipoApagado.ItemData(cmbTipoApagado.NewIndex) = EWX_SHUTDOWN
cmbTipoApagado.AddItem "REBOOT"
cmbTipoApagado.ItemData(cmbTipoApagado.NewIndex) = EWX_REBOOT
cmbTipoApagado.ListIndex = 0
End Sub

espero te ayude esto Reinicia, apaga, y cierra sesion de winows..

nos vemos

[rdorlando]

vampirito me puedes decir como te ha ido con el codigo, ya que GeoAvila mando un codigo extenso y creo que completo, ya que no es obligacion de nadie tomarce este trabajo (la mayoria no lohacemos, no es la finalidad del foro, aunque esta bueno); yo cundo tengo el tiempo, la situacion lo amerita,el codigo lo se porque yo lo he creado o lo tengo a mano lo suelo mandar, pero son las menos.