fullscreen visual basic

[Beakdan]

Esto debe servirte (cierra la ventana con Alt+F4 o pon algo para que pueda cerrarse)...

Código:

Private Declare Function SetWindowPos Lib "user32" ( _
		ByVal hWnd As Long, _
		ByVal hWndInsertAfter As Long, _
		ByVal x As Long, _
		ByVal Y As Long, _
		ByVal cx As Long, _
		ByVal cy As Long, _
		ByVal uFlags As Long) As Long
 
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" ( _
		ByVal hWnd As Long, _
		ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" ( _
		ByVal hWnd As Long, _
		ByVal nIndex As Long, _
		ByVal dwNewLong As Long) As Long
 
Private Const HWND_TOPMOST As Long = -1
Private Const GWL_STYLE	 As Long = (-16)
Private Const WS_DLGFRAME	As Long = &H400000
Private Const WS_BORDER	 As Long = &H800000
Private Const WS_THICKFRAME As Long = &H40000
 
Private Sub Form_Load()
Dim lWinStyle As Long
 
	'Me.BackColor = vbBlack
 
	lWinStyle = GetWindowLong(Me.hWnd, GWL_STYLE)
	lWinStyle = lWinStyle And Not WS_BORDER
	lWinStyle = lWinStyle And Not WS_DLGFRAME
	lWinStyle = lWinStyle And Not WS_THICKFRAME
 
	SetWindowLong Me.hWnd, GWL_STYLE, lWinStyle
 
	SetWindowPos Me.hWnd, HWND_TOPMOST, 0, 0, _
				Screen.Width \ Screen.TwipsPerPixelX, _
				Screen.Height \ Screen.TwipsPerPixelY, 0&
End Sub

Hasta luego.