Acceso sólo a una IP.

[u_goldman]

A ver, hice este script, no está super probado, pero fíjate si te sirve

<%
'Valida rango de ip xxx.xxx.x.*
Function valida_ipDeArreglo(ip)
'obtenemos una variable para sacar la cantidad de
'caracteres después del último punto
cuenta = len(ip) - (len(ip) - (instrRev(ip, ".") - 1))
'cortamos la cadena para devolver el rango xxx.xxx.x*
valida_ipDeArreglo = left(ip, cuenta)
End Function

Function entra_ip(que_ips)
'Está en false para descartar desde el inicio
permitido = false
'Obtenemos el arreglo en base al argumento que_ips separado por ","
arrIPSPermitidas = split(que_ips, ",")
'Obtenemos la IP del visitante
ip = request.servervariables("REMOTE_ADDR")
'Obtenemos el rango de esta ip para ver si es el permitido
rango= valida_ipDeArreglo(ip)

'Entramos al ciclo desde que i valga 0(indice de 0 ), hasta
'el número máximo en el índice del arreglo
For i = 0 to uBound(arrIPSPermitidas)
'Obtenemos el rango para cada una de las IP's permitidas
'dentro del arreglo
RangoIPArreglo= valida_ipDeArreglo(arrIPSPermitidas(i))
'Si el rango de la ip del visitante es igual a cualquier
'rango de las ip's de nuestro arreglo entonces es permitido
If rango = RangoIPArreglo Then
permitido = true
'Regresa el valor, en este caso true
entra_ip= permitido
'Sale de la función
Exit Function
End If
Next
'Si no se encontró ningún rango igual, permanece en la función
'y regresa el valor de permitido, en este caso false
entra_ip= permitido
End Function

'Llamamos a la función y le pasamos las ip's que queremos permitir
'separadas por "," no dejar espacios entre ellas
esta_ip= entra_ip("192.168.0.255,193.168.0.500")
'Aqui solo vemos que valor devuelve la función, para evaluar la IP
Response.Write(esta_ip)
%>

Salu2,