Agregar diferentes palabras a un formato final

[pkj]

Creo que con "3 textbox" te refieres a 3 combobox con listas de frutas.

De todas formas me he tomado la libertad de crearte el programa y explicarte lo que hace, ya que veo que tienes poca idea y pienso que si estudias un codigo sabiendo lo que debe hacer y con explicaciones igual te sirve (a ti o a otros) para aprender algunas cosas.

Solo hay que crear un form y ponerle 4 textbox, 3 combobox y un commandbutton

Código vb:

Option Explicit
Const constante = "Jugo de "
 
Private Sub Form_Load()
  
  ' cargamos los textbox
  ' recuerda configurar en las propiedades de los textbox Multiline=True
  Text1.Text = "pera" & vbCrLf & "manzana" & vbCrLf & "fresas"
  Text2.Text = "melón" & vbCrLf & "durazno" & vbCrLf & "moras"
  Text3.Text = "patilla" & vbCrLf & "piña" & vbCrLf & "naranja"
  
  ' limpiamos el text4
  Text4.Text = ""
  
  ' cargamos los combobox y seleccionamos el primer elemento de cada uno
  CargaCombos 0, 0, 0
  
  
End Sub
 
Private Sub CargaCombos(ByVal Index1 As Integer, ByVal Index2 As Integer, ByVal Index3 As Integer)
  
  ' para no escribir todos los nombres que podrian ser cientos
  ' lo hacemos de un modo en que no importe cuantos haya
  
  ' y ademas se puede usar para añadir elementos a los combos
  ' cuando se escribe en los textbox durante la ejecucion (ver evento Text1_LostFocus)
  ' para eso añado 3 parametros que serviran para recordar que
  ' elementos estaban seleccionados
  
  ' creamos una matriz de strings
  Dim matriz() As String
  
  Dim f As Integer
  
  ' llenamos la matriz con las palabras de cada textbox
  matriz = Split(Text1.Text, vbCrLf)
  ' y pasamos los elementos a un combobox
  Combo1.Clear ' (primero se vacia el combo)
  For f = 0 To UBound(matriz)
    Combo1.AddItem matriz(f)
  Next f
  
  ' asi con los 3 combos
  matriz = Split(Text2.Text, vbCrLf)
  Combo2.Clear
  For f = 0 To UBound(matriz)
    Combo2.AddItem matriz(f)
  Next f
  Combo3.Clear
  matriz = Split(Text3.Text, vbCrLf)
  For f = 0 To UBound(matriz)
    Combo3.AddItem matriz(f)
  Next f
  
  ' y por ultimo seleccionamos un elemento de cada combo
  If Combo1.ListCount > Index1 Then Combo1.ListIndex = Index1
  If Combo2.ListCount > Index2 Then Combo2.ListIndex = Index2
  If Combo3.ListCount > Index3 Then Combo3.ListIndex = Index3
  
End Sub
 
 
Private Sub Text1_LostFocus()
  ' cada vez que un textbox cambia se recargan los combos
  CargaCombos Combo1.ListIndex, Combo2.ListIndex, Combo3.ListIndex
End Sub
 
Private Sub Text2_LostFocus()
  ' cada vez que un textbox cambia se recargan los combos
  CargaCombos Combo1.ListIndex, Combo2.ListIndex, Combo3.ListIndex
End Sub
 
Private Sub Text3_LostFocus()
  ' cada vez que un textbox cambia se recargan los combos
  CargaCombos Combo1.ListIndex, Combo2.ListIndex, Combo3.ListIndex
End Sub
 
Private Sub Command1_Click()
  'al pulsar el boton puedes...
    
  ' limpiamos el text4
  Text4.Text = ""
  
  'y escribimos la constante y la combinacion de lo elegido en los 3 combos:
  Text4.Text = constante & Combo1.Text & " - " & Combo2.Text & " - " & Combo3.Text
  
  
  MsgBox "pulsa una tecla"
 
  ' o podemos escribir todos como en el ejemplo
  Text4.Text = ""
  Dim f As Integer
  ' pero para eso hay que asegurarse de que los combos tienen la misma cantidad de elementos:
  Dim Elementos As Integer
  Elementos = Combo1.ListCount - 1
  If Combo2.ListCount - 1 < Elementos Then Elementos = Combo2.ListCount - 1
  If Combo3.ListCount - 1 < Elementos Then Elementos = Combo3.ListCount - 1
  For f = 0 To Elementos
    Text4.Text = Text4.Text & constante & Combo1.List(f) & " - " & Combo2.List(f) & " - " & Combo3.List(f)
 
    ' si no es el ultimo añadimos un salto de linea
    If f < Elementos Then Text4.Text = Text4.Text & vbCrLf
  Next f
 
  'tambien puedes mostrar todas las combinaciones posibles haciendo 3 bucles for uno dentro de otro
  
End Sub
 

Como verás se puede incluso añadir frutas a las listas.

Saludos