Mostrar el ultimo comentario ingresado, de primero en el Textbox

[pkj]

Lo que puedes hacer es guardar el log a la inversa y así es más fácil de examinar.

Código vb:

Option Explicit
 
Private Sub Command1_Click()
  Static Contador As Double
  Contador = Contador + 1
  GuardarDato App.Path & "\FicheroLog.txt", "Prueba " & Contador
 
  ' y mostrar el último dato añadido
  'Text1.Text = LeerUltimoLog(App.Path & "\FicheroLog.txt")
  ' o añadirlo al comienzo:
  Text1.Text = LeerUltimoLog(App.Path & "\FicheroLog.txt") & vbCrLf & Text1.Text
End Sub
 
Function GuardarDato(FicheroLog As String, Dato As String) As Long
  Dim NumFichero As Integer
  Dim Texto As String
  On Local Error GoTo ErrorFunction
  NumFichero = FreeFile
  Open FicheroLog For Binary Access Read Write As #NumFichero
  Texto = input(FileLen(FicheroLog), #NumFichero)
  Close #NumFichero
  If Texto <> "" Then
    Texto = Dato & vbCrLf & Texto
  Else
    Texto = Dato
  End If
  NumFichero = FreeFile
  Open FicheroLog For Output As #NumFichero
  Print #NumFichero, Texto
  Close #NumFichero
  Exit Function
ErrorFunction:
  GuardarDato = Err.Number
  Err.Clear
  On Local Error Resume Next
  Close #NumFichero
End Function
 
Function LeerUltimoLog(FicheroLog As String) As String
  Dim NumFichero As Integer
  On Local Error GoTo ErrorFunction
  NumFichero = FreeFile
  Open FicheroLog For Input As #NumFichero
  Line Input #NumFichero, LeerUltimoLog
  Close #NumFichero
  Exit Function
ErrorFunction:
  Err.Clear
  On Local Error Resume Next
  Close #NumFichero
End Function
 

Saludos