Le hice una pequeña modificación:
Código ASP:
Ver original<%
If Request("tabla") = "" then
tabla = Request.Form("tabla")
else
tabla = Request("tabla")
end if%>
<form action="consultatabla.asp" method="post">
Tabla a consultar:<br>
<input name="tabla" type="text" value="<%= tabla %>"><br><br>
<input name="" type="submit"><br>
</form>
<%
'Simplemente Configurar el string de conexion'
'y la tabla a mostrar, en las siguientes variables'
StrConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source="& Server.MapPath("/[COLOR="Red"][B]RUTA de la base de datos[/B][/COLOR]")
Set oConn = Server.CreateObject("ADODB.Connection")
oConn.Open StrConn
if tabla <> "" then
'-----------------------------------------------------------------------------'
'Configuraciones visuales (no obligatorias)'
color_datos = "#000000"
color_titulos = "#FFFFFF"
'los colores de fondo de la tabla'
fondo_color_datos = "#cbebde"
fondo_color_titulos = "#475f70"
'la letra (font) de los datos'
font_datos = "Verdana"
font_titulos = "Verdana"
'el tamaño (size) de la letra'
size_datos = "11"
size_titulos = "11"
'-----------------------------------------------------------------------------'
'No tocar mas abajo de esta linea si no se sabe lo que se hace'
'-----------------------------------------------------------------------------'
sql = "SELECT * FROM ["& Trim(tabla) & "]"
Set RS = Server.CreateObject("ADODB.RecordSet")
RS.Open sql, oConn, 3, 1
Response.Write vbTab & "<TABLE cellpadding='3' BORDER='1' WIDTH='100%' bordercolor='#000000'>"
Response.Write vbTab & "<TR>" & vbCrLf
For I = 0 To RS.Fields.Count - 1
Response.Write "<TD align='center' bgcolor='"& fondo_color_titulos &"' "
Response.Write "style='color: "& color_titulos &"; font-family:"& font_titulos &"; font-size: "& size_titulos &"'><B>"
Response.Write RS.Fields(I).Name
Response.Write "</B></TD>" & vbCrLf
Next 'I
Response.Write vbTab & "</TR>" & vbCrLf
Do While not RS.EOF
Response.Write vbTab & "<TR>" & vbCrLf
For I = 0 To RS.Fields.Count - 1
Response.Write "<TD align='left' bgcolor='"& fondo_color_datos &"' "
Response.Write "style='color: "& color_datos &"; font-family:"& font_datos &"; font-size: "& size_datos &"'><B>"
Response.Write RS.Fields(I)
if isnull(RS.Fields(I)) or RS.Fields(I) = "" then response.write " "
Response.Write "</B></TD>" & vbCrLf
Next 'I
Response.Write vbTab & "</TR>" & vbCrLf
RS.MoveNext
Loop
Response.Write vbTab & "</TABLE>"
RS.Close
Set RS = Nothing
oConn.Close
Set oConn = Nothing
end if
'-----------------------------------------------------------------------------'
'Lista de tablas'
'-----------------------------------------------------------------------------'
Response.Write "<BR><BR><BR><BR>"
Const adSchemaTables = 20
Set oConn = Server.CreateObject("ADODB.Connection")
oConn.Open StrConn
strFiltro = Array(Empty,Empty,Empty,"TABLE")
set rstSchema = oConn.OpenSchema(adSchemaTables,strFiltro)
Do Until rstSchema.EOF%>
Tabla: <a href="?tabla=<%=rstSchema("TABLE_NAME")%>"><%=rstSchema("TABLE_NAME")%></a><br/>
<%rstSchema.MoveNext
Loop
%>
Ahora donde mostraba el nombre de la tabla es un enlace que pinchando abre la página con la tabla, sin tener que escribirla en la caja de texto.