Ver archivos del servidor

[Myakire]

mmmmm

Tienes esta linea en tu código que baja el archivo?:

Response.AddHeader "Content-Disposition", "attachment; filename=" & variableConElNombreDelArchivo

Ejemplo que descarga archivos del servidor

Código ASP:

Response.Buffer = True
Dim strFilePath, strFileSize, strFileName
Const adTypeBinary = 1
strFilePath = Request.QueryString("File")
strFileSize = Request.QueryString("Size")
strFileName = Request.QueryString("Name")
Response.Clear
 
'printlnf(strFilePath & "  " & strFileSize & "  " & strFileName)
 
Set objStream = Server.CreateObject("ADODB.Stream")
objStream.Open
objStream.Type = adTypeBinary
objStream.LoadFromFile strFilePath
strFileType = lcase(Right(strFileName, 4))
Select Case strFileType
  Case ".asf"
    ContentType = "video/x-ms-asf"
  Case ".avi"
    ContentType = "video/avi"
  Case ".txt"
    ContentType = "text/plain"
  Case ".doc"
    ContentType = "application/msword"
  Case ".zip"
    ContentType = "application/zip"
  Case ".xls"
    ContentType = "application/vnd.ms-excel"
  Case ".gif"
    ContentType = "image/gif"
  Case ".jpg", "jpeg"
    ContentType = "image/jpeg"
  Case ".wav"
    ContentType = "audio/wav"
  Case ".mp3"
    ContentType = "audio/mpeg3"
  Case ".mpg", "mpeg"
    ContentType = "video/mpeg"
  Case ".rtf"
    ContentType = "application/rtf"
  Case ".htm", "html"
    ContentType = "text/html"
  Case ".asp"
    ContentType = "text/asp"
  Case ".pdf"
    ContentType = "application/pdf"
  Case Else
    'Handle All Other Files
    ContentType = "application/octet-stream"
End Select
Response.AddHeader "Content-Disposition", "attachment; filename=" & strFileName
Response.AddHeader "Content-Length", strFileSize
Response.Charset = "UTF-8"
Response.ContentType = ContentType
Response.BinaryWrite objStream.Read
Response.Flush
objStream.Close
Set objStream = Nothing