Comparar 2 Arreglos de dimensiones distintas

[u_goldman]

Me puse curioso, es que son las birras que tengo encima, a ver si te funciona algo asi:

Código:

<%
Option Explicit
Dim docs1,docs2,i,j,cssClass

Sub Inicializa()
	docs1 = Array(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16)
	docs2 = Array(1,4,7,12)
End Sub

Function DetectaRepetidos(arr1,arr2,cssClass)
	Dim arr1copia, arr2Copia

	if isArray(arr1) and isArray(arr2) then
		if uBound(arr1) > uBound(arr2) then
			arr1Copia = arr1
			arr2Copia = arr2
		else
			arr1Copia = arr2
			arr2Copia = arr1		
		end if

		for i = 0 to uBound(arr1Copia)
			for j = 0 to uBound(arr2Copia)
				if arr2Copia(j) = arr1Copia(i) then
					arr1Copia(i) = "<span class="""&cssClass&""">"&arr1Copia(i)&"</span>"
					exit for
				end if
			next
		next		
	end if
	
	DetectaRepetidos = arr1Copia
End Function

Sub ImprimeArreglo(arr1)
	if isArray(arr1) then
		for i = 0 to uBound(arr1)
			Response.Write(arr1(i))
		next
	else
		Response.Write("Nada que imprimir")
	end if
End Sub
%>

<style type="text/css">
	.subrayar
	{
		font-weight: bold;
		text-decoration: underline;
	}
</style>
<%
cssClass = "subrayar"
Call Inicializa()
Call ImprimeArreglo(DetectaRepetidos(docs1,docs2,cssClass))
%>