copiar un archivo a un determinado directorio.

[juanpablomonte]

ok Amigos, lo encontre.
En realidad esta desarrollado por RootK ( Un idolo total ! )
Aqui les dejo el codigo por las dudas alguien lo necesite.

Código:

 '/// <summary>
    '/// Permite copiar archivos y carpetas    
    '/// </summary>
    '/// <param name="diSource">Directorio origen</param>
    '/// <param name="diDestination">Directorio Destino</param>
    '/// <param name="overwrite">Sobreescribir archivos</param>
    '/// <remarks>Creado por Eduardo S. Almazán (RootK - www.forosdelweb.com)</remarks>
    Private Sub CopyFiles(ByVal diSource As DirectoryInfo, ByVal diDestination As DirectoryInfo, _
                          ByVal blOverwrite As Boolean)

        Dim diSourceSubDirectories() As DirectoryInfo
        Dim fiSourceFiles() As FileInfo

        'obtengo todos los archivos del directorio origen
        fiSourceFiles = diSource.GetFiles()
        'obtengo los subdirectorios (si existen)
        diSourceSubDirectories = diSource.GetDirectories()

        'si no existe el directorio destino crearlo
        If Not diDestination.Exists Then diDestination.Create()

        'Usar la recursividad para navegar por los subdirectorios
        'e ir obteniendo los archivos hasta llegar al final
        For Each diSourceSubDirectory As DirectoryInfo In diSourceSubDirectories
            CopyFiles(diSourceSubDirectory, New DirectoryInfo(diDestination.FullName & "\" & _
            diSourceSubDirectory.Name), blOverwrite)
        Next

        For Each fiSourceFile As FileInfo In fiSourceFiles
            fiSourceFile.CopyTo(diDestination.FullName + "\" + fiSourceFile.Name, blOverwrite)
        Next

    End Sub

Para llamarlo:

     'ruta del directorio origen
     Dim diSource As New DirectoryInfo("C:\folderOrigen")
     'ruta del directorio destino
     Dim diDestiny As New DirectoryInfo("C:\folderDestino")
     CopyFiles(diSource, diDestiny, True)

Gracias a Todos; Suerte !