Para no estar creando decenas de botones, lo recomendable es crearlos dinámicamente por AS. Este código es de diez minutos (cutre pero optimizable):
Código:
// reseteamos la variable de recorrido
var n:Number = 0;
// se crea la matriz con los menús. Se puede usar un xml o bbdd...
var menu_array:Array = new Array("Inicio", "Contacto", "Imagenes", "Videos", "Portfolio", "Descargas");
// Necesitamos un formato de texto para embeder la fuente
var formato:TextFormat = new TextFormat();
formato.font = "Fuente 1"; // este es el nombre que le he dado a la fuente
formato.color = 0xFFFFFF; // color de la fuente
function menuItem() {
// se crea el mc en el que irá el texto
var mc:MovieClip = this.createEmptyMovieClip("menu_"+n, n);
mc._x = 10;
mc._y = 10+20*n;
mc._alpha = 0;
// se crea el campo de texto
var mi:TextField = mc.createTextField("menu_txt", this.getNextHighestDepth(), 0, 0, 100, 20);
mi.embedFonts = true;
mi.selectable = false;
mi.text = menu_array[n];
mi.setTextFormat(formato);
this["menu_"+n].onEnterFrame = function() {
this._alpha += 5;
if (this._alpha>=100) {
delete this.onEnterFrame;
}
};
n++;
if (n>=menu_array.length) {
clearInterval(id); // se acaba cuando hemos recorrido toda la matriz
}
}
// iniciamos el proceso de mostrar los botones cada 50 milisegundos
var id:Number = setInterval(this, "menuItem", 50);
Para embeder una fuente, hay que ir a la biblioteca y desplegar el menú. Ahí está la opción de 'nueva fuente' y a partir de aquí no tiene ninguna complicación. Al terminar, hay que hacer clic derecho sobre el símbolo de la fuente en la biblioteca y vinvularlo para exportarlo para AS (en mi ejemplo, identificador 'Fuente 1').
Y no hay que hacer nada más.
Puede sonar a mucho rollo, pero es sencillo. Ante cualquier duda puedo pasarte el fla.
Saludos!