Hola, he visto que preguntabas algo de presentar la fecha y la hora en tus RSS.
Si deseas presentar la hora, tienes que ponerla en formato RFC-822. ¿Cómo se consigue esto?. Pues con estas funciones:
Código:
<%
'Para el sistema de fechas en español
'(cámbialo si no es ese)
Session.LCID = 1034
'función para pasar el día en español, a día en inglés
'ojo: el primer día de la semana es el domingo, y el último, el sábado
function DiaEnIngles(NumeroDeDia)
select case NumeroDeDia
case 1
DiaEnIngles = "Sun"
case 2
DiaEnIngles = "Mon"
case 3
DiaEnIngles = "Tue"
case 4
DiaEnIngles = "Wed"
case 5
DiaEnIngles = "Thu"
case 6
DiaEnIngles = "Fri"
case 7
DiaEnIngles = "Sat"
end select
end function
'función para pasar el mes en español, a mes en inglés
function MesEnIngles(NumeroDeMes)
select case NumeroDeMes
case 1
MesEnIngles = "Jan"
case 2
MesEnIngles = "Feb"
case 3
MesEnIngles = "Mar"
case 4
MesEnIngles = "Apr"
case 5
MesEnIngles = "May"
case 6
MesEnIngles = "Jun"
case 7
MesEnIngles = "Jul"
case 8
MesEnIngles = "Aug"
case 9
MesEnIngles = "Sep"
case 10
MesEnIngles = "Oct"
case 11
MesEnIngles = "Nov"
case 12
MesEnIngles = "Dec"
end select
end function
'función para poner un cero delante, si el día, o el mes solo tienen 1 caracter
function CeroDelante(periodo)
if len(periodo) = 1 then
CeroDelante = "0" & periodo
else
CeroDelante = periodo
end if
end function
'función para poner la fecha en formato RFC-822 (necesaria para RSS)
function FormatoDeFechaRFC822(fecha)
FormatoDeFechaRFC822 = DiaEnIngles(DatePart("w",fecha)) & ", " & CeroDelante(DatePart("d", fecha)) & " " & MesEnIngles(DatePart("m",fecha)) & " " & DatePart("yyyy", fecha) & " " & CeroDelante(DatePart("h", fecha)) & ":" & CeroDelante(DatePart("n", fecha)) & ":" & CeroDelante(DatePart("s",fecha)) & " GMT"
end function
%>
En RSS 2.0, se añadiría este item (suponiendo que quieras sumar 5 horas, a la hora del servidor, por aquello de la diferencia horaria):
Código:
response.write "<pubDate>" & FormatoDeFechaRFC822(DateAdd("h", +5, rs("fecha"))) & "</pubDate>"
Espero que te sirva. Un ejemplo de como queda, lo puedes ver en las RSS de la web de mi firma.
Salu2