Cuenta atrás en Flash

[luistar]

Hola
has de tener en cuenta que los meses se cuentan de 0 (enero) a 11 (diciembre)
por ejemplo para la fecha: 01/01/2010
sería: Date(2009,11,31,23,59,59);

Iniciado por promotore

A ver quién es el titán que ahora lo tunea para quela fecha se la demos a través de un txt. Porque a mí no me ha salido...

Y seguro que debe ser muy fácil, pero he estado una hora y nada. Me parece que se me da mejor programar el finde que el actionscript.

Siento responder tarde, ya no frecuento el foro, pero para quien lo necesite:

Código:

//aumenta un cero si es menor que 10 (ejemp: 5 será 05) 
var mascero:Function = function (n:Number):String{return n<10?'0'+n:n;} 

var fecha_limite:Date;

//para cargar la fecha de un archivo externo
var fecha_limite_lv:LoadVars = new LoadVars();
fecha_limite_lv.onLoad = function(ok:Boolean){
	if(ok){
		//actualizamos la fecha limite (año, mes 0-11, dia, hora 0-23, minuto 0-59, segundo 0-59)
		fecha_limite = new Date(this.anio,this.mes,this.dia,this.hora,this.minuto,this.segundo);
		//hacemos andar  el contador
		_root.onEnterFrame = cuentaAtras;
	}
}

//
var cuentaAtras:Function = function(){ 
	//la fecha_actual actual
	var fecha_actual:Date = new Date(); 

	//verificamos el tiempo faltante
	var falta:Number = (fecha_limite.getTime() - fecha_actual.getTime())/10; 
	
	if(falta > 0){ 
		//hacemos los cálculos
		var d:Number = Math.floor(falta/8640000); //dias
		var h:Number = Math.floor((falta%8640000)/360000); //horas
		var m:Number = Math.floor((falta%360000)/6000); //minutos
		var s:Number = Math.floor((falta%6000)/100); //segundos
		var cs:Number = Math.floor((falta%100)); //centésimas de segundo
		//lo mostramos en un campo de texto
		falta_txt.text = mascero(d)+'d : '+mascero(h)+'h : '+mascero(m)+'m : '+mascero(s)+'s : '+mascero(cs)+'cs'; 
	}else{ 
		//si ya no falta nada
		falta_txt.text = 'la fecha limite ya pasó'; 
		delete this.onEnterFrame; 
	} 
} 

//cargamos la fecha del archivo externo
fecha_limite_lv.load('fecha_limite.txt');

stop();

en el archivo fecha_limite.txt defines las valores
por ejemplo para la fecha: 01/01/2010

Código:

&anio=2009&mes=11&dia=31&hora=23&minuto=59&segundo=59