Dibujar filas y columnas segun datos de BD

[3pies]

Entendido. Mira este ejemplo que tengo hecho para un sitio que tengo a medias (este ejemplo es completo). El ejemplo es para 2 columnas, pero puedes adaptarlo con poco esfuerzo. El ejemplo cierra todas las etiquetas <TD> y <TR>, aunque haya registros impares (por ejemplo 3 registros):

Código:

<%
'Si no está vacía la consulta
if not rs.EOF then
	contador=0
	Do While not rs.EOF
		contador=contador+1
		%>
		<td width="50%" align="center" valign="top"><b><%=AcomodarTexto(InicialesEnMayusculas(rs("nombre")))%></b>
		<%
		'Si el usuario quiere mostrar su foto, la colocamos aquí
		if not isnull(rs("foto")) and rs("foto")<>"" and rs("mostrarfoto")=true and rs("fotoaceptada")=true then
		%>
			<br><img border="0" src="../fotosusuarios/<%=rs("foto")%>" onerror="src='../fotosusuarios/errorenfotodelcolaborador.jpg';" alt="" width="100" height="125">
		<%else%>
			<br><img border="0" src="../fotosusuarios/usuariosinfoto.jpg" onerror="src='../fotosusuarios/colaboradorsinfoto.jpg';" alt="" width="100" height="125">
		<%end if
		'Si quiere mostrar su email, lo colocamos aquí
		if rs("mostraremail")=true then
		%>
			<br>
			<%
			'Llamamos a la función ReemplazarArroba
			Response.Write ReemplazarArroba(rs("email"))
			%>
		<%end if%>
		</td>
		<%if contador mod 2=0 and totalcolaboradores>contador then%>
			</tr><tr><td colspan="2">&nbsp;</td></tr><tr><td colspan="2">&nbsp;</td></tr><tr>
		<%elseif contador mod 2<>0 and totalcolaboradores=contador then%>
			<td width="50%" align="center" valign="top">&nbsp;</td>
		<%end if
		'Nos movemos al siguiente registro
		rs.MoveNext
	Loop
'Si no hay colaboradores
else
	response.write "<td colspan=""2"" valign=""top""><div align=""justify"">En estos momentos, y dado que hace poco tiempo que estamos en la red, no disponemos de colaboradores.</div></td>"
end if
'Cerramos y limpiamos los objetos
rs.close
oConn.close
set rs=nothing
set oConn=nothing
%>

No obstante, si quieres algo más sencillo aquí tienes un ejemplo (usa el buscador del foro): http://www.forosdelweb.com/showthrea...ighlight=filas y aquí otro: http://www.forosdelweb.com/showthrea...light=columnas y más que hay :)